ファイルパスとファイル名を取得する -VBA基礎-

Function GetFilePathAndName(toWorkbook As Workbook, withSheetName As String, fileType As String, fileExt As String, range_Path As String, range_Name As String)
'    Dim toWorkbook As workbook  '出力先ブック
'    Dim withSheetName As String '出力先シート名
'    Dim fileType As String      'ファイル選択対象とするファイルの種類名
'    Dim fileExt As String       'ファイル選択対象とするファイルの拡張子
'    Dim range_Path As String    '取得したファイルパスの表示先セル
'    Dim range_Name As String    '取得したファイル名の表示先セル
    
    Dim fullPath As Variant     'ファイルの保存先とファイル名
    Dim pos As Integer          'ファイル名の文字数
    Dim filePath As String      'ファイルの保存先
    Dim fileName As String      'ファイル名
    
    Dim dialogReturn As Integer

    
    With Application.FileDialog(msoFileDialogFilePicker)
        ' 選択できるファイルの種類を指定する
        .Filters.Clear
        .Filters.Add fileType, fileExt
        ' 複数ファイルの選択を禁止
        .AllowMultiSelect = False
        
        ' ファイル選択画面を表示
        dialogReturn = .Show
        ' ファイル選択したら、ファイルパスとファイル名に分けてセルに表示する
        If dialogReturn <> 0 Then
            fullPath = .SelectedItems(1)
            ' ファイル名の文字数を確認し、ファイルパスとファイル名に分割する
            pos = InStrRev(fullPath, "\")
            filePath = Left(fullPath, pos - 1)
            fileName = Mid(fullPath, pos + 1)
            ' 取得結果をシートのセルに出力
            toWorkbook.Worksheets(withSheetName).Range(range_Path).Value = filePath
            toWorkbook.Worksheets(withSheetName).Range(range_Name).Value = fileName
        Else
            MsgBox "ファイルパスとファイル名が取得できませんでした"
        End If
    End With
    
End Function

Function GetFilePath(toWorkbook As Workbook, withSheetName As String, range_Path As String)
'    Dim toWorkbook As workbook  '出力先ブック
'    Dim withSheetName As String '出力先シート名
'    Dim range_Path As String    '取得したファイルパスの表示先セル
    
    Dim filePath As String      'ファイルの保存先
    
    Dim dialogReturn As Integer

    
    With Application.FileDialog(msoFileDialogFolderPicker)
        
        ' ファイル選択画面を表示
        dialogReturn = .Show
        ' ファイル選択したら、ファイルパスとファイル名に分けてセルに表示する
        If dialogReturn <> 0 Then
            filePath = .SelectedItems(1)
            ' 取得結果をシートのセルに出力
            toWorkbook.Worksheets(withSheetName).Range(range_Path).Value = filePath
        Else
            MsgBox "ファイルパスが取得できませんでした"
        End If
    End With
    
End Function

Sub Button1()
    'ファイルを選択するとファイルパスとファイル名をセルに表示する処理を呼び出す
    Dim toWorkbook As Workbook '出力先ブック
    Dim withSheetName As String '出力先シート名
    Dim fileType As String      'ファイル選択対象とするファイルの種類名
    Dim fileExt As String       'ファイル選択対象とするファイルの拡張子
    Dim range_Path As String    '取得したファイルパスの表示先セル
    Dim range_Name As String    '取得したファイル名の表示先セル
    
    Set toWorkbook = ThisWorkbook
    withSheetName = "sheet1"
    fileType = "EXCELファイル"
    fileExt = "*.xlsx"
    range_Path = "C3"
    range_Name = "C4"
    
    Call GetFilePathAndName(toWorkbook, withSheetName, fileType, fileExt, range_Path, range_Name)
    
End Sub

Sub Button2()
    'フォルダを選択するとファイルパスをセルに表示する処理を呼び出す
    Dim toWorkbook As Workbook '出力先ブック
    Dim withSheetName As String '出力先シート名
    Dim range_Path As String    '取得したファイルパスの表示先セル
    
    Set toWorkbook = ThisWorkbook
    withSheetName = "sheet1"
    range_Path = "C8"
    
    Call GetFilePath(toWorkbook, withSheetName, range_Path)
    
End Sub